Return to configure.in CVS log

Up to [Development] / xfs-cmds / acl

configure.in patch from Andreas re default configure paths.

dnl unpacking check - this file must exist
AC_INIT(include/acl.h)
AC_CONFIG_HEADER(include/config.h)

pkg_name="acl"
AC_SUBST(pkg_name)

AC_PREFIX_DEFAULT(/usr)

#
# Note: the following environment variables may be set to override the
# defaults (to change paths and/or executables, build parameters, etc):
#
#   DEBUG  OPTIMIZER  MALLOCLIB
#   PLATFORM  DISTRIBUTION  INSTALL_USER  INSTALL_GROUP
#   MAKE  CC  LD  TAR  ZIP  AWK  SED  ECHO  RPM  LIBTOOL
#   MSGFMT  MSGMERGE  XGETTEXT
#

DEBUG=${DEBUG:-'-DDEBUG'}		# -DNDEBUG
OPTIMIZER=${OPTIMIZER:-'-g'}		# -O2
MALLOCLIB=${MALLOCLIB:-''}		# /usr/lib/libefence.a

dnl Debug build?
debug_build="$DEBUG"
AC_SUBST(debug_build)

dnl Optimization options?
opt_build="$OPTIMIZER"
AC_SUBST(opt_build)

dnl Alternate malloc library?
malloc_lib="$MALLOCLIB"
AC_SUBST(malloc_lib)

dnl Set version
. ./VERSION

pkg_version=${PKG_MAJOR}.${PKG_MINOR}.${PKG_REVISION}
pkg_release=$PKG_BUILD
AC_SUBST(pkg_version)
AC_SUBST(pkg_release)

pkg_platform=`uname -s`
pkg_distribution="Generic $pkg_platform"
pkg_platform=`echo $pkg_platform | tr 'A-Z' 'a-z'`
test -z "$PLATFORM" || pkg_platform="$PLATFORM"
test -z "$DISTRIBUTION" || pkg_distribution="$DISTRIBUTION"
AC_SUBST(pkg_distribution)
AC_SUBST(pkg_platform)

pkg_user=root
test -z "$INSTALL_USER" || pkg_user="$INSTALL_USER"
AC_SUBST(pkg_user)

pkg_group=root
test -z "$INSTALL_GROUP" || pkg_group="$INSTALL_GROUP"
AC_SUBST(pkg_group)

dnl check if user wants their own C compiler
test -z "$CC" && AC_PROG_CC
cc=$CC
AC_SUBST(cc)

dnl check if users wants their own make
test -z "$MAKE" && AC_PATH_PROG(MAKE, make, /usr/bin/make)
make=$MAKE
AC_SUBST(make)

dnl check if users wants their own linker
test -z "$LD" && AC_PATH_PROG(LD, ld, /usr/bin/ld)
ld=$LD
AC_SUBST(ld)

dnl check if the tar program is available
test -z "$TAR" && AC_PATH_PROG(TAR, tar)
tar=$TAR
AC_SUBST(tar)

dnl check if the gzip program is available
test -z "$ZIP" && AC_PATH_PROG(ZIP, gzip, /bin/gzip)
zip=$ZIP
AC_SUBST(zip)

dnl check if the makedepend program is available
test -z "$MAKEDEPEND" && AC_PATH_PROG(MAKEDEPEND, makedepend, /bin/true)
makedepend=$MAKEDEPEND
AC_SUBST(makedepend)

dnl check if the rpm program is available
test -z "$RPM" && AC_PATH_PROG(RPM, rpm, /bin/rpm)
rpm=$RPM
AC_SUBST(rpm)

dnl .. and what version is rpm
rpm_version=0
test -x $RPM && \
	rpm_version=`$RPM --version | awk '{print $NF}' | awk -F. '{print $1}'`
AC_SUBST(rpm_version)

dnl At some point in rpm 4.0, rpm can no longer build rpms, and
dnl rpmbuild is needed (rpmbuild may go way back; not sure)
dnl So, if rpm version >= 4.0, look for rpmbuild.  Otherwise build w/ rpm

if test $rpm_version -ge 4; then
	AC_PATH_PROG(RPMBUILD, rpmbuild)
	rpmbuild=$RPMBUILD
else
	rpmbuild=$RPM
fi
AC_SUBST(rpmbuild)

dnl check if symbolic links are supported
AC_PROG_LN_S

dnl check if user wants their own awk, sed and echo
test -z "$AWK" && AC_PATH_PROG(AWK, awk, /bin/awk)
awk=$AWK
AC_SUBST(awk)
test -z "$SED" && AC_PATH_PROG(SED, sed, /bin/sed)
sed=$SED
AC_SUBST(sed)
test -z "$ECHO" && AC_PATH_PROG(ECHO, echo, /bin/echo)
echo=$ECHO
AC_SUBST(echo)

dnl ensure libtool is installed
test -z "$LIBTOOL" && AC_PATH_PROG(LIBTOOL, libtool,,/usr/bin)
if test "$LIBTOOL" = ""; then
	echo
	echo 'FATAL ERROR: libtool does not seem to be installed.'
	echo $pkg_name cannot be built without a working libtool installation.
	exit 1
fi
libtool=$LIBTOOL
AC_SUBST(libtool)

dnl libtool to build libraries static only?
AC_ARG_ENABLE(shared,
	[ --enable-shared=[yes/no] Enable use of shared libraries [default=yes]],,
	enable_shared=yes)
AC_SUBST(enable_shared)

dnl will we be making use of gettext?
AC_ARG_ENABLE(gettext,
	[ --enable-gettext=[yes/no] Enable alternate language support [default=yes]],,
	enable_gettext=yes)
test $enable_gettext = "yes" && AC_DEFINE(ENABLE_GETTEXT)
AC_SUBST(enable_gettext)

dnl check if the msgfmt, msgmerge, xgettext programs are available
if test "$enable_gettext" = yes; then
	test -z "$MSGFMT" && AC_CHECK_PROG(MSGFMT, msgfmt, /usr/bin/msgfmt)
	msgfmt=$MSGFMT
	AC_SUBST(msgfmt)
	test -z "$MSGMERGE" && AC_CHECK_PROG(MSGMERGE, msgmerge, /usr/bin/msgmerge)
	msgmerge=$MSGMERGE
	AC_SUBST(msgmerge)

	test -z "$XGETTEXT" && AC_CHECK_PROG(XGETTEXT, xgettext, /usr/bin/xgettext)
	xgettext=$XGETTEXT
	AC_SUBST(xgettext)

	if test "$XGETTEXT" = ""; then
		echo
		echo 'FATAL ERROR: xgettext does not seem to be installed.'
		echo $pkg_name cannot be built without a working gettext installation.
		exit 1
	fi
fi

dnl man pages (source)
dnl also check if man page source is gzipped
dnl (usually on Debian, but not Redhat pre-7.0)
have_zipped_manpages=false
for d in ${prefix}/share/man ${prefix}/man ; do
    if test -f $d/man1/man.1.gz
    then
	have_zipped_manpages=true
	break
    fi
done
AC_SUBST(have_zipped_manpages)

dnl checks for extended attributes header and library
AC_CHECK_HEADERS([attr/xattr.h attr/error_context.h])
if test "$ac_cv_header_attr_xattr_h" != "yes"; then
	echo
	echo 'FATAL ERROR: attr/xattr.h does not exist.'
	echo 'Install the extended attributes (attr) development package.'
	echo 'Alternatively, run "make install-lib" from the attr source.'
	exit 1
fi
if test "$ac_cv_header_attr_error_context_h" != "yes"; then
	echo
	echo 'FATAL ERROR: attr/error_context.h does not exist.'
	echo 'Upgrade the extended attributes (attr) development package.'
	echo 'Alternatively, run "make install-dev" from the attr source.'
	exit 1
fi
AC_CHECK_LIB(attr, getxattr,, [
	echo
	echo 'FATAL ERROR: could not find a valid Extended Attributes library.'
	echo 'Install the extended attributes (attr) development package.'
	echo 'Alternatively, run "make install-lib" from the attr source.'
	exit 1
])
libattr="-lattr"
test -f `pwd`/../attr/libattr/libattr.la && libattr="`pwd`/../attr/libattr/libattr.la"
test -f /usr/lib/libattr.la && libattr="/usr/lib/libattr.la"
AC_SUBST(libattr)

AC_FUNC_GCC_VISIBILITY

dnl build definitions for use in Makefiles
AC_OUTPUT(include/builddefs)