[BACK]Return to NGpatch.S CVS log [TXT][DIR] Up to [Development] / linux-2.6-xfs / arch / sparc64 / lib
File: [Development] / linux-2.6-xfs / arch / sparc64 / lib / NGpatch.S (download)

Revision 1.1, Mon May 29 16:35:25 2006 UTC (11 years, 4 months ago) by nathans.longdrop.melbourne.sgi.com
Branch: MAIN
CVS Tags: HEAD 

Merge up to 2.6.17-rc5.
Merge of 2.6.x-xfs-melb:linux:26065a by kenmcd.

/* NGpatch.S: Patch Ultra-I routines with Niagara variant.
 *
 * Copyright (C) 2006 David S. Miller <davem@davemloft.net>
 */

#define BRANCH_ALWAYS	0x10680000
#define NOP		0x01000000
#define NG_DO_PATCH(OLD, NEW)	\
	sethi	%hi(NEW), %g1; \
	or	%g1, %lo(NEW), %g1; \
	sethi	%hi(OLD), %g2; \
	or	%g2, %lo(OLD), %g2; \
	sub	%g1, %g2, %g1; \
	sethi	%hi(BRANCH_ALWAYS), %g3; \
	sll	%g1, 11, %g1; \
	srl	%g1, 11 + 2, %g1; \
	or	%g3, %lo(BRANCH_ALWAYS), %g3; \
	or	%g3, %g1, %g3; \
	stw	%g3, [%g2]; \
	sethi	%hi(NOP), %g3; \
	or	%g3, %lo(NOP), %g3; \
	stw	%g3, [%g2 + 0x4]; \
	flush	%g2;

	.globl	niagara_patch_copyops
	.type	niagara_patch_copyops,#function
niagara_patch_copyops:
	NG_DO_PATCH(memcpy, NGmemcpy)
	NG_DO_PATCH(___copy_from_user, NGcopy_from_user)
	NG_DO_PATCH(___copy_to_user, NGcopy_to_user)
	retl
	 nop
	.size	niagara_patch_copyops,.-niagara_patch_copyops