// This script tracks time between packet queue and xmit.
// The information is provided to userspace using Memory Mapped Values (mmv)
// which are updated every second and are readable by a PCP pmda.

global inst, instance_latency, instance_count

// Set up the mmv and make it available
probe begin
{
  indom = mmv_add_indom(1, "xmit device",
			       "list of network transmit devices")
  // fallback instance device "eth0" if none specified
  if (argc == 1) {
    argv[1] = "eth0"
    argc++ 
  }
  // create instances for each network device
  for (i=1; i<argc; i++) {
    dev = argv[i]
    printf("%s\n", dev)
    inst[dev] = mmv_add_instance(0, dev)
    mmv_add_indom_instance(indom, inst[dev])
  }
  // create the metrics
  xmit_latency_metric = mmv_add_metric("xmit_latency", 1, MMV_TYPE_NUMBER,
  	       	 		MMV_SEM_COUNTER,
				mmv_units(0, 1, 0, 0, MMV_TIME_NSEC, 0),
				1, "xmit latency metric",
				"sum of latency for xmit device")
  xmit_count_metric = mmv_add_metric("xmit_count", 1, MMV_TYPE_NUMBER,
  	       	    		MMV_SEM_COUNTER,
				mmv_units(0, 0, 1, 0, 0, 0),
				1, "xmit count metric",
				"number of packets for xmit device")

  mmv_stats_start(43, 0)

  // provide mappings for all the instance metrics
  for (i=1; i<argc; i++) {
    dev = argv[i]
    instance_latency[dev] = mmv_lookup_value(xmit_latency_metric, inst[dev])
    instance_count[dev] = mmv_lookup_value(xmit_count_metric, inst[dev])
  }

  do_update()
}

function do_update() {
  // for each of the instances
  foreach(dev in instance_latency) {
    if(@count(skb_queue_t[dev])) {
      mmv_set_value(instance_latency[dev], @sum(skb_queue_t[dev]))
      mmv_set_value(instance_count[dev], @count(skb_queue_t[dev]))
    } else {
      mmv_set_value(instance_latency[dev], 0)
      mmv_set_value(instance_count[dev], 0)
    }
  }
}

// periodically update the info
probe timer.s(1) { do_update() }

probe end { mmv_stats_stop() }

// probes to track the information

global skb_queue_start_t, skb_queue_t

probe kernel.trace("net_dev_queue") {
  skb_queue_start_t[$skb] = gettimeofday_ns();
}

probe kernel.trace("net_dev_start_xmit"), kernel.trace("net_dev_xmit") {
  t = gettimeofday_ns();
  st =  skb_queue_start_t[$skb]
  if (st){
    skb_queue_t[kernel_string($dev->name)] <<< t - st
    delete skb_queue_start_t[$skb]
  }
}